Bricscad v11 für Windows

Finn Rasmussen

Hallo, wie kann ich ein pdf-Datei mit Layerstruktur erstellen? evtl. mit Acrobat 9 Pro?

Roy Klein Gebbinck

If by layer structure you mean a list of layer names you may find this lisp useful. It prints the layer names to the text screen and also creates a text file that you can print to pdf.

(defun GetAllNamesInTable (table / ent lst)
  (setq ent (tblnext table 'T))
  (while ent
    (setq lst (cons (cdr (assoc 2 ent)) lst))
    (setq ent (tblnext table))
  )
  (reverse lst)
)

(defun c:LiLa () (c:ListLayers))
(defun c:ListLayers ( / lst file)
  (setq lst
    (cons
      (strcat "Layers in drawing " (getvar 'dwgprefix) (getvar 'dwgname))
      (vl-sort (GetAllNamesInTable "layer") '<)
    )
  )
  (textscr)
  (mapcar
    '(lambda (a) (princ "\n") (princ a))
    lst
  )
  (setq file (open (strcat (getvar 'dwgprefix) "Layers in drawing " (getvar 'dwgname) ".txt") "w"))
  (mapcar
    '(lambda (a) (write-line a file))
    lst
  )
  (close file)
  (princ)
)

(princ "\nCommand: ListLayers or LiLa ")
(princ)