showing present UCS
Hello everybody.
Is there a way to let the UCS-icon show which planar UCS /View is the present one? I don't draw very often in 3D, and it is every time a suprise what view i selected.
Just keep the present view button darker or something like that?
Greets
Sander de Geus
DrontenBouw BV
Comments
-
By the way, i'm using V11.4.6.
0 -
Hi Sander,
I guess the first thing to check is that your ._UCSICON is ON, and set to Corner so that it remains visible.
You could customise the View -> Look From pulldown menu with some DIESEL to provide indication as to which view is current. To do this:
- Type CUI at the command prompt to open the menu customisation dialogue.
- Under the Menus Tab browse and expand the menu tree till you find the 'Look From' menu.
- Select on one of the commands e.g. Top
- The Menu Item will have a Diesel line. You can customise this with a Diesel function. For Top you would put the following: $(if,$(and,$(=, $(index,0,$(getvar, _viewdir)), 0),$(=, $(index,1,$(getvar, _viewdir)), 0),$(=, $(index,2,$(getvar, _viewdir)), 1)),!.)
- Once you have done this pick the Apply Button to save your changes.
The full list for Planar views are as follows:
;Top
;Top view (plan view)
;^c^c._vpoint;_rotate;270;90
;(0 0 1)
$(if,$(and,$(=, $(index,0,$(getvar, _viewdir)), 0),$(=, $(index,1,$(getvar, _viewdir)), 0),$(=, $(index,2,$(getvar, _viewdir)), 1)),!.)
;Front
;Front view
;^c^c._vpoint;_rotate;270;0
;(0 -1 0)
$(if,$(and,$(=, $(index,0,$(getvar, _viewdir)), 0),$(=, $(index,1,$(getvar, _viewdir)), -1),$(=, $(index,2,$(getvar, _viewdir)), 0)),!.)
;Right
;Right view
;^c^c._vpoint;_rotate;0;0
;(1 0 0)
$(if,$(and,$(=, $(index,0,$(getvar, _viewdir)), 1),$(=, $(index,1,$(getvar, _viewdir)), 0),$(=, $(index,2,$(getvar, _viewdir)), 0)),!.)
;Left
;Left view
;^c^c._vpoint;_rotate;180;0
;(-1 0 0)
$(if,$(and,$(=, $(index,0,$(getvar, _viewdir)), -1),$(=, $(index,1,$(getvar, _viewdir)), 0),$(=, $(index,2,$(getvar, _viewdir)), 0)),!.)
;Back
;Back view
;^c^c._vpoint;_rotate;90;0
;(0 1 0)
$(if,$(and,$(=, $(index,0,$(getvar, _viewdir)), 0),$(=, $(index,1,$(getvar, _viewdir)), 1),$(=, $(index,2,$(getvar, _viewdir)), 0)),!.)
;Bottom
;Bottom view
;^c^c._vpoint;_rotate;90;270
;(0 0 -1)
$(if,$(and,$(=, $(index,0,$(getvar, _viewdir)), 0),$(=, $(index,1,$(getvar, _viewdir)), 0),$(=, $(index,2,$(getvar, _viewdir)), -1)),!.).)For Isometric Views you could try the following:
;Front Right
;Front Right Isometric View
;^c^c._vpoint;_rotate;330;30
; (0.75 -0.433013 0.5)
$(if,$(and,$(>, $(index,0,$(getvar, _viewdir)), 0),$(<, $(index,1,$(getvar, _viewdir)), 0),$(>, $(index,2,$(getvar, _viewdir)), 0)),!.)
;Front Left
;Front Left Isometric View
;^c^c._vpoint;_rotate;240;30
;(-0.43301 -0.75 0.5)
$(if,$(and,$(<, $(index,0,$(getvar, _viewdir)), 0),$(<, $(index,1,$(getvar, _viewdir)), 0),$(>, $(index,2,$(getvar, _viewdir)), 0)),!.)
;Back Right
;Back Right Isometric View
;^c^c._vpoint;_rotate;60;30
;(0.43301 0.75 0.5)
$(if,$(and,$(>, $(index,0,$(getvar, _viewdir)), 0),$(>, $(index,1,$(getvar, _viewdir)), 0),$(>, $(index,2,$(getvar, _viewdir)), 0)),!.)
;Back Left
;Back Left Isometric View
;^c^c._vpoint;_rotate;150;30
;(-0.75,0.43301,0.5)
$(if,$(and,$(<, $(index,0,$(getvar, _viewdir)), 0),$(>, $(index,1,$(getvar, _viewdir)), 0),$(>, $(index,2,$(getvar, _viewdir)), 0)),!.)Note:
- The above functions work by checking the current view direction (_VIEWDIR) x, y, and z values against what they should be for that view direction.
- !. places a tick, or square frame in the icon area of the menu. Alternative you could use ~ to grey out, or just some text.
- With Isometric views indication is based on an approximation, not an exact verification. This is because DIESEL lacks the math and/or comparitive functions required to do this. If Bricscad included $(rtos) you could be more precise.
- This approach should work on a Toolbars, but with V11 it doesn't seem to update automatically. You need to force it by say toggling object snaps (F3) on and off.
Hope that you find this of use.
Regards,
Jason Bourhill
0 -
Looks like the diesel doesn't work with international references. In my previous post you need to change _viewdir to viewdir for it to work.
Regards,
Jason Bourhill
0
