Matchprop Multiple Selection

Scott McKenzie

The functionality of the Match Properties command has been greatly improved in V12.1.5 - it is great that as soon as you select an object (after picking the source) that the properties are set.  THANK YOU!!!  This has bugged me since I started with Bricscad.  However the ability to select multiple entities with a window or other method has been removed since  V12.1.4.  Is this an option in the program? - I am finding myself attempting to draw crossing windows as opposed to the individual selection req'd.

Roy Klein Gebbinck

Seems like an oversight on the part of the programmers. Below is a lisp fix.

; Uncomment the next two lines (= remove the semicolon), to replace the matchprop command:
; (command "_.undefine" "matchprop")
; (defun c:matchprop () (c:MatchPropFix))

(terpri)

(defun kg:Pickset->EnameList (ss / i result)
  (if ss
    (repeat (setq i (sslength ss))
      (setq result (cons (ssname ss (setq i (1- i))) result))
    )
  )
)

(defun c:MatchPropFix ( / base ss)
  (if (setq base (car (entsel "\nMatchPropFix: Select entity to copy properties from: ")))
    (while (setq ss (ssget "_:SI"))
      (mapcar
        '(lambda (a)
          (command "_.matchprop" base a "")
        )
        (kg:Pickset->EnameList ss)
      )
    )
  )
  (princ)
)

The fix will also work on V11.4.6, adding the 'instant update' effect to that version.

Roy Klein Gebbinck

There is a small mistake in the code of my previous post:

(ssget "_:SI")

Should be:

(ssget "_:S")

But even with the mistake the code will work on V11 and V12.
After correcting the mistake the lisp will also work on V10.

Joseph Ciccarelli

Thanks a lot... This lips work perfectly. It's now included in my "on_start.lsp".

 

Thanks again Roy!

Scott McKenzie

Sweet thanks!

Daniel Eiszele

I have raised a support request for this topic as no one has mentioned doing so.

 

Regards,