lisp to replace the *layer rename functionality of autocad

Hi Colin,
if you want to prefix ALL Layers then the suggestion of Roy above is the best way to go...
But if you want to prefix only selected Layers , as you asked, then you need a filter string to select Layers !
So i changed the routine above to do just this .
You have to type a filter ( you can include blanks in the input string ) to select Layers to be prefixed
You can Type for example Z,DEF,G to select only layers containing in their name the specified strings,
in the example all layers containing in their names the above strings...
The routine uses the lisp Function wcmatch so i attach a PDF explaining the way you form the filter string!

I attach the routine

;; Applies a prefix to selected Layers in a Drawing except the 0 layer and Defpoints Layer ;;;
(defun C:LP ( / acadDocument layertable layName prefix filter)
  (vl-load-com)
  (setq prefix (getstring T "\nEnter Layer Prefix to Apply to selected Layers: "))
  (setq filter (getstring T "\nEnter Layer Filter to select Layers to be prefixed or press Enter for all Layers: "))
  (setq acadDocument (vla-get-activedocument (vlax-get-acad-object)))
  (setq layertable (vla-get-layers acadDocument))
  (vlax-map-collection layertable 'layer-mod)
  (princ)
)

(defun layer-mod (layertableRec)
  (setq layName (vlax-get-property layertableRec 'Name))
  (cond
    ((= filter "")
     (if (NOT(wcmatch layName "Defpoints,DEFPOINTS,0" ))
       (vla-put-Name layertableRec (strcat prefix layName))
       ) ;endif
     )
    (T
     (if (AND (NOT(wcmatch layName "Defpoints,DEFPOINTS,0" ))
          (wcmatch layName filter)
          )
       (vla-put-Name layertableRec (strcat prefix layName))
       )
     )
    )
 )

Example
Prefix = 399x_
Filter = ***Z*,*DEF*,*G***
Result of prefixed Layers